1. Escolha um elemento da lista, denominado pivô.
2. Rearranje a lista de forma que todos os elementos anteriores ao pivô sejam menores que ele, e todos os elementos posteriores ao pivô sejam maiores que ele. Ao fim do processo o pivô estará em sua posição final e haverá duas sub listas não ordenadas.
3. Recursivamente ordene a sub lista dos elementos menores e a sub lista dos elementos maiores.

{$A-}

var vetor : array[1..10] of integer;

procedure quicksort(inicio, fim : integer);
var i, j, pivo, aux : integer;
begin
  i := inicio;
  j := fim;
  pivo := vetor[(inicio + fim) div 2];

  while (i <= j) do
  begin
    while (vetor[i] < pivo) and (i < fim) do
      i := i+1;

    while (vetor[j] > pivo) and (j > inicio) do
      j := j-1;

    if (i <= j) then
    begin
      aux := vetor[i];
      vetor[i] := vetor[j];
      vetor[j] := aux;
      i := i+1;
      j := j-1;
    end;
  end;

  if (j > inicio) then
    quicksort(inicio, j);

  if (i < fim) then
    quicksort(i, fim);
end;

procedure cria_vetor;
var i : integer;
begin
  randomize;
  for i:=1 to 10 do
    vetor[i] := random(100)+1;
end;

procedure imprime_vetor;
var i : integer;
begin
  for i:=1 to 10 do
    write(vetor[i], ' ');
  writeln;
end;

begin
  cria_vetor;

  writeln('Vetor desordenado:');
  imprime_vetor;
  writeln;

  quicksort(1, 10);

  writeln('Vetor ordenado:');
  imprime_vetor;
end.